
<%
' This is always a good idea when dealing with
' cookies!  Especially cookies and a redirect!
Response.Buffer = True

' This script handles both the adding and deleting of cookies
Dim strCookieName  ' The name of the cookie we're processing
Dim strCookieValue ' The value to be assigned to it

' Get the values passed in by the other script
strCookieName  = CStr(Request.QueryString("name"))
strCookieValue = CStr(Request.QueryString("value"))

' If no name is passed in then we don't do anything
If strCookieName <> "" Then
	
	' Set the value of the cookie.  You need to set the
	' value to something even if you're trying to delete
	' it! If you set it to "" then it won't work! If the
	' value passed in is nothing then we know to expire
	' the cookie by setting it's expiration date to
	' yesterday, otherwise we set it to expire tomorrow.
	If strCookieValue <> "" Then
		Response.Cookies(strCookieName) = strCookieValue
		Response.Cookies(strCookieName).Expires = Date() + 1
	Else
		Response.Cookies(strCookieName) = "must be something!"
		Response.Cookies(strCookieName).Expires = Date() - 1
	End If
End If

' Bounce users back to the display page
Response.Redirect("cookie.asp") 
%>